sys/web/sites/matrix.nix


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52

{ config, lib, ... }:
with lib; let
  cfg = config.local.web.sites.matrix;
  inherit (config.local) domains;
in
{
  options.local.web.sites.matrix = {
    enable = mkEnableOption "matrix proxy site";

    proxyUrl = mkOption {
      type = types.str;
    };
  };

  config = mkIf cfg.enable {
    local.web = {
      enable = mkDefault true;
      ownedCerts = [ "matrix" ];

      sites.portal.enable = true;
    };

    services.nginx.virtualHosts =
      let
        proxyLocation =
          throwIf (hasSuffix "/" cfg.proxyUrl)
            "matrix site: a trailing slash *must not* be used here"
            cfg.proxyUrl;
      in
      {
        ${domains.exdev.main}.locations."/.well-known/matrix".proxyPass = proxyLocation;

        ${domains.matrix.main} = {
          forceSSL = true;
          useACMEHost = domains.matrix.main;

          locations = {
            "/".extraConfig = ''
              return 403;
            '';

            # Forward all Matrix API calls to the synapse Matrix homeserver. A trailing slash
            # *must not* be used here.
            "/_matrix".proxyPass = proxyLocation;

            # Forward requests for e.g. SSO and password-resets.
            "/_synapse/client".proxyPass = proxyLocation;
          };
        };
      };
  };
}