sys/users.nix


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46

{ lib, config, pkgs, ... }:
with lib; let
  cfg = config.local;
in
{
  config = {
    sound.enable = true;
    hardware.pulseaudio.enable = true;

    services.xserver = {
      enable = true;
      videoDrivers = cfg.videoDrivers ++ [ "modesetting" "fbdev" ];
      libinput.enable = true;
      displayManager.startx.enable = true;
    };

    services.udev.packages = [
      pkgs.android-udev-rules
    ];

    programs = {
      dconf.enable = true;
      zsh.enable = true;
    };

    environment.pathsToLink = [ "/share/zsh" ];

    users.users = mapAttrs
      (username: user: {
        isNormalUser = true;

        inherit (user) uid;
        description = user.gecos;

        group = username;
        extraGroups = [ "users" ] ++ user.groups;

        shell = if user.allowLogin then pkgs.zsh else null;
      })
      cfg.users;

    users.groups = mapAttrs (_: user: { inherit (user) gid; }) cfg.users // {
      adbusers.gid = 1008;
    };
  };
}