home/default.nix


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191

{ self, nixpkgs, nur }:
{ lib, config, pkgs, ... }:
with lib; {
  imports = [ ./unfree.nix ];

  nixpkgs.overlays = [ nur.overlay self.overlay ];

  nix.registry = {
    "nixpkgs".flake = nixpkgs;
    "nur".flake = nur;

    "system".to = {
      type = "path";
      path = "/home/ale/nix";
    };
  };

  home = {
    # This value determines the Home Manager release that your
    # configuration is compatible with. This helps avoid breakage
    # when a new Home Manager release introduces backwards
    # incompatible changes.
    #
    # You can update Home Manager without changing this value. See
    # the Home Manager release notes for a list of state version
    # changes in each release.
    stateVersion = "21.11";

    username = "ale";
    homeDirectory = "/home/ale";

    sessionVariables = {
      EDITOR = "nvim";
      LESSHISTFILE = "/dev/null";
    };

    language.base = "es_CR.UTF-8";

    file = let
      symlink = path: { source = config.lib.file.mkOutOfStoreSymlink path; };
      #TODO: No sirve, creo que por readline
      devNull = symlink "/dev/null";
    in {
      "vtmp" = symlink "/run/user/1000/vtmp";
      ".calc_history" = devNull;
      ".units_history" = devNull;

      ".shenvs".text = let
        keeps = { gcKeep ? [] }: concatStringsSep "\n" (map toString gcKeep);
      in keeps (import ../shenvs/config.nix pkgs.local.shenvs);
    };

    packages = import ./path.nix pkgs;
  };

  fonts.fontconfig.enable = true;

  gtk = {
    enable = true;
    gtk3.bookmarks = [ "file:///home/ale/vtmp" "file:///home/ale/tmp" ];

    gtk2.extraConfig = ''
      gtk-toolbar-style=GTK_TOOLBAR_BOTH_HORIZ
      gtk-menu-images=1
      gtk-button-images=1
    '';

    font = {
      package = pkgs.noto-fonts;
      name = "Noto Sans Regular";
      #size = 14; <- caga layout de páginas
    };

    theme = {
      package = pkgs.materia-theme;
      name = "Materia-dark";
    };
  };

  qt = {
    enable = true;
    platformTheme = "gtk";
  };

  xdg = {
    enable = true;
    configFile = {
      "i3/config".text = import ./i3-config.nix {
        inherit (pkgs) i3lock-color xautolock;
        inherit (pkgs.xorg) setxkbmap;
        inherit (pkgs.local) tmux-lift;

        alacritty = config.programs.alacritty.package;
        i3status-rust = config.programs.i3status-rust.package;
        rofi = config.programs.rofi.finalPackage;
      };
    };
  };

  systemd.user.tmpfiles.rules = [
    "d %t/vtmp 0700"
  ];

  xsession = {
    enable = true;
    # Cambiar po windowManager.i3.enable al migrar
    windowManager.command = "${pkgs.i3-gaps}/bin/i3";
  };

  programs = {
    home-manager.enable = true;

    zsh = {
      enable = true;
      enableAutosuggestions = true;
      enableSyntaxHighlighting = true;
      initExtra = import ./zshrc.nix pkgs;
    };

    alacritty = {
      enable = true;
      settings = import ./alacritty.nix;
    };

    firefox = {
      enable = true;

      profiles."main.profile" = {
        id = 0;
        name = "default";
      };

      extensions = with pkgs.nur.repos.rycee.firefox-addons; [
        decentraleyes
        darkreader
        keepassxc-browser
        old-reddit-redirect
        privacy-badger
        ublock-origin
        umatrix
      ];
    };

    git = {
      enable = true;
      userName = "Alejandro Soto";
      userEmail = "alejandro@34project.org";
    };

    i3status-rust = {
      enable = true;
    };

    neovim = {
      enable = true;
      withRuby = false;
      withPython3 = false;

      extraConfig = ''
        set number         " Enable line numbering
        set relativenumber " Enable relative line numbering
        set tabstop=4      " Set tap stop to 4
        set shiftwidth=4   " Set shift width to 4 (same as tabstop)
        set viminfo=       " No tracking
      '';
    };

    rofi = {
      enable = true;
      theme = "DarkBlue";
    };

    tmux = {
      enable = true;
      aggressiveResize = true;
      clock24 = true;
      escapeTime = 10;
      terminal = "xterm-256color";
      keyMode = "vi";

      extraConfig = ''
        set -g mouse on
        set -ga update-environment " LIFT_PID"
        set -g set-titles on
        set -g renumber-windows on
        set -sa terminal-overrides ',xterm-termite:RGB'
        set -g status-right "#{?window_bigger,[#{window_offset_x}#,#{window_offset_y}] ,} %H:%M %d-%b-%y"
      '';
    };
  };
}