flake.nix


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83

{
  inputs = {
    nixpkgs.url = "github:nixos/nixpkgs/nixos-22.11";
    unstable.url = "github:nixos/nixpkgs";

    home-manager = {
      url = "github:nix-community/home-manager/release-22.11";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    nur.url = "github:nix-community/NUR";
    impermanence.url = "github:nix-community/impermanence";
    hm-isolation.url = "/home/ale/hm-isolation";
  };

  outputs =
    { self, nixpkgs, unstable, home-manager, nur, impermanence, hm-isolation, ... }: let
      system = "x86_64-linux";

      pkgs = pkgsNoLocal.extend self.overlays.default;
      pkgsNoLocal = importPkgs nixpkgs;

      importPkgs = flake: import flake {
        inherit system;

        config.android_sdk.accept_license = true;
        overlays = [ nur.overlay ];
      };

      util = import ./util;
      inherit (util pkgs.lib) importAll;

      local = import ./pkgs;
    in with pkgs.lib; {
      packages.${system} = local pkgs pkgsNoLocal;

      overlays.default = final: prev: {
        local = local final prev;
        unstable = (importPkgs unstable).extend self.overlays.default;
      };

      nixosConfigurations = let
        hostConfig = host: (makeOverridable nixpkgs.lib.nixosSystem) {
          inherit pkgs system;

          modules = [
            ./sys
            host
            nixpkgs.nixosModules.notDetected
            impermanence.nixosModule
          ];
        };
      in mapAttrs (_: hostConfig) (importAll { root = ./sys/platform; });

      homeConfigurations = let
        registry = { ... }: {
          config.nix.registry = {
            "nixpkgs".flake = nixpkgs;
            "unstable".flake = unstable;
            "nur".flake = nur;
          };
        };

        home = platform: home-manager.lib.homeManagerConfiguration {
          inherit pkgs;

          modules = [
            ./home
            platform
            registry
            hm-isolation.homeManagerModule
          ];
        };

        platformHome = name: platform: let
          value = home platform;
        in {
          inherit value;
          name = "${value.config.home.username}@${name}";
        };
      in mapAttrs' platformHome (importAll { root = ./home/platform; });
    };
}