{ config, lib, pkgs, ... }:
with lib; {
  config = mkIf (!config.home.isolation.active) {
    home.pointerCursor = {
      package = pkgs.gnome.adwaita-icon-theme;

      gtk.enable = true;
      name = "Adwaita";
      x11.enable = true;
    };

    programs = {
      firefox = {
        enable = true;

        package = pkgs.firefox.override {
          nativeMessagingHosts = [ pkgs.passff-host ];
        };

        profiles."main.profile" = {
          id = 0;
          name = "default";

          extensions = with pkgs.nur.repos.rycee.firefox-addons; [
            decentraleyes
            darkreader
            old-reddit-redirect
            passff
            privacy-badger
            ublock-origin
            umatrix
          ];
        };
      };

      i3status-rust.enable = true;

      rofi = {
        enable = true;
        theme = "DarkBlue";
      };

      tmux = {
        enable = true;
        aggressiveResize = true;
        clock24 = true;
        escapeTime = 10;
        terminal = "xterm-256color";
        keyMode = "vi";

        extraConfig = ''
          set -g mouse on
          set -ga update-environment " LIFT_PID"
          set -g set-titles on
          set -g renumber-windows on
          set -sa terminal-overrides ',xterm-termite:RGB'
          set -g status-right "#{?window_bigger,[#{window_offset_x}#,#{window_offset_y}] ,} %H:%M %d-%b-%y"
          bind-key X set-window-option synchronize-panes\; display-message "synchronize-panes is now #{?pane_synchronized,on,off}"
        '';
      };
    };

    xdg.configFile."i3/config".text = pkgs.callPackage ./i3-config.nix {
      inherit (pkgs.local) st tmux-lift;

      i3status-rust = config.programs.i3status-rust.package;
      rofi = config.programs.rofi.finalPackage;
    };

    xsession = {
      enable = true;
      # Cambiar por windowManager.i3.enable al migrar
      windowManager.command = "${pkgs.i3-gaps}/bin/i3";
    };

  };
}