1 files changed, 91 insertions, 6 deletions
diff --git a/pkgs/default.nix b/pkgs/default.nix
index 1b11af9..6d36ce0 100644
--- a/pkgs/default.nix
+++ b/pkgs/default.nix
@@ -1,11 +1,96 @@
-final: prev:
+{
+  final,
+  prev,
+  flakes,
+}:
 with prev.lib; let
-  inherit (final) callPackage;
+  inherit (final) callPackage fetchpatch;
 in {
-  override = {};
+  lib = callPackage ./lib {};
 
-  athena-bccr = callPackage ./athena-bccr {};
-  snapborg = final.python3Packages.callPackage ./snapborg {};
-  socialpredict = callPackage ./socialpredict {};
+  btclone = callPackage ./btclone {};
+  gem5 = callPackage ./gem5.nix {gem5ISA = "x86";};
+  git-aliases = callPackage ./git-aliases.nix {};
+  increment-zone-serials = callPackage ./increment-zone-serials {};
+  kbuild-standalone = callPackage ./kbuild-standalone.nix {};
+  mssql-tools = callPackage ./mssql-tools.nix {};
+  oregano = callPackage ./oregano {};
+  pass-bcr = callPackage ./pass-bcr {};
+  pass-tail = callPackage ./pass-tail {};
+  rqlite = callPackage ./rqlite.nix {};
+  rv8 = callPackage ./rv8.nix {};
+  scripts = callPackage ./scripts {};
+  simple-scalar = callPackage ./simple-scalar {};
   spliit = callPackage ./spliit {};
+  tmux-lift = callPackage ./tmux-lift {};
+  tmux-open = callPackage ./tmux-open {};
+  tmux-pass = callPackage ./tmux-pass.nix {};
+
+  sysret-static = callPackage ./zola-static {
+    site = "sysret.org";
+    src = "${flakes.self}/sysret.org";
+  };
+
+  st = prev.st.override {
+    conf = import ./st.nix {};
+
+    patches = [
+      (fetchpatch {
+        url = "https://st.suckless.org/patches/clipboard/st-clipboard-0.8.3.diff";
+        sha256 = "cbb37675e9b4986836c19aadacc616a006df81c9bf394e9e3573e164fa1867cf";
+      })
+    ];
+  };
+
+  override =
+    {
+      home-assistant-custom-components =
+        prev.home-assistant-custom-components
+        // {
+          dreame_vacuum = final.home-assistant.python.pkgs.callPackage ./dreame-vacuum.nix {};
+          smartthinq_sensors = final.home-assistant.python.pkgs.callPackage ./smartthinq-sensors.nix {};
+        };
+
+      home-assistant-custom-lovelace-modules =
+        prev.home-assistant-custom-lovelace-modules
+        // {
+          xiaomi-vacuum-map-card = final.callPackage ./lovelace-xiaomi-vacuum-map-card {};
+        };
+
+      # Tomado de all-packages.nix
+      msmtp = callPackage ./msmtp {};
+
+      postfix = callPackage ./postfix {inherit (prev) postfix;};
+      xandikos = final.python3Packages.callPackage ./xandikos {inherit (prev) xandikos;};
+    }
+    // (
+      let
+        makePyOverrides = version: let
+          name = "python3${toString version}";
+        in {
+          inherit name;
+
+          value = prev.${name}.override {
+            packageOverrides = nextPy: prevPy: {
+              cocotb = nextPy.callPackage ./cocotb {inherit (prevPy) cocotb;};
+              cocotbext-wishbone = nextPy.callPackage ./cocotb/exts/wishbone.nix {};
+              find-libpython = nextPy.callPackage ./find-libpython.nix {};
+              hdl-convertor = nextPy.callPackage ./hdl-convertor {};
+              hdl-convertor-ast = nextPy.callPackage ./hdl-convertor/ast.nix {};
+              iced-x86 = nextPy.callPackage ./iced-x86 {};
+            };
+          };
+        };
+
+        pyVersionRange' = start: end: let
+          next = end + 1;
+        in
+          if prev ? "python3${toString next}"
+          then pyVersionRange' start next
+          else range start end;
+
+        pyVersionRange = start: pyVersionRange' start start;
+      in
+        listToAttrs (map makePyOverrides (pyVersionRange 9))
+    );
 }